Źle działająca funkcja getdate.

0

Witam. Mam mały problem z funkcją getdate. Mianowicie, chyba źle odczytuje aktualną datę z komputera. Mam następujący program:

program odczyt;

uses
  crt, dos;

type
  rosoba = record
    imie, nazwisko : string;
    rokurodzenia : byte;
  end;

var
  f : file of rosoba;
  osoba : rosoba;
  rok, m, d, dt : word;

begin
  getdate(rok, m, d, dt);
  clrscr;
  assign(f, 'osoby.dta');
  rewrite(f);
  repeat
    writeln('Podaj imie, lub wcisnji Enter aby zakonczyc');
    readln(osoba.imie);
    if osoba.imie <> '' then
    begin
      writeln('Podaj nazwisko');
      readln(osoba.nazwisko);
      writeln('Podaj rok urodzenia');
      readln(osoba.rokurodzenia);
      write(f, osoba);
    end;
  until osoba.imie = '';
  close(f);
  clrscr;
  reset(f);
  while not eof(f) do
  begin
    read(f, osoba);
    write('Imie: ');
    writeln(osoba.imie);
    write('Nazwisko: ');
    writeln(osoba.nazwisko);
    write('Wiek: ');
    writeln(rok - osoba.rokurodzenia,' lat');
    writeln;
  end;
  close(f);
  readln;
end.

I po podaniu roku urodzenia np. 1990 potem wyświetla mi w polu wiek 1813 lat. Nie wiem co jest nie tak i proszę o pomoc w rozwiązaniu tego problemu.

0
type
  rosoba = record
    imie, nazwisko : string; // Co za absurd ! String musi mieć określoną długość !
    rokurodzenia : byte;
  end;

;-)

1

U ciebie rokurodzenia jest typu byte, a powinna być typu integer. Byte przechowuje liczby tylko z zakresu 0-255.

0

W TP jeżeli string nie ma określonej długości to przyjmuje maksymalny rozmiar, czyli 255 o ile dobrze pamiętam.

Tak, tylko 255 to trochę za dużo, zwłaszcza zważywszy ograniczone zasoby pamięciowe w 16-bitowym programie.

proponuję coś takiego:

type
  string30 = string[30];
  rosoba = record
    imie, nazwisko : string30;
    rokurodzenia : word;
  end;

i będzie przenośne do Delphi.

0
notaras napisał(a)

U ciebie rokurodzenia jest typu byte, a powinna być typu integer. Byte przechowuje liczby tylko z zakresu 0-255.

Dzięki, tego właśnie nie zauważyłem.

1 użytkowników online, w tym zalogowanych: 0, gości: 1