Drukowanie Image i Printer

Witam... Mam pytanie...chodzi mi o drukowanie w dobrej rozdzielczości.

Drukuje na dwa sposoby:

Image1.Canvas.TextOut(0,0,'Przykładowy tekst');
printer.BeginDoc;
printer.Canvas.Draw(0,0,image1.Picture.Bitmap);
printer.EndDoc;
//-----------------------------------
printer.BeginDoc;
printer.Canvas.TextOut(0,0,'Przykładowy tekst');
printer.EndDoc;

I drugi sposób ma delikatnie ładniejszy(bardziej tłusty) wydruk. Od czego to jest uzależnione?
A najładniejszy wydruk wychodzi mi drukując z RichEdit.

Problem w tym, że z RichEdit nie moge za bardzo drukować bo drukuje tekst i obrazki dynamicznie generowane.

Czy jest możliwość wydrukowania na drukarce z jakością wydruku (tak jak RichEdit)?

Pozdrawiam...

Masz tu gotowy komponent którego zrobiłem, a jest oparty na przykładzie bodajże z serwisu 4programmers.net

unit ImagePrint;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, Printers;

type
  TImagePrint = class(TComponent)
  private
    { Private declarations }
    procedure DrawImage(Canvas: TCanvas; DestRect: TRect; ABitmap: TBitmap);
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
    procedure PrintImage(Image: TImage; ZoomPercent: Integer);
  end;

procedure Register;

implementation

{$R ImagePrint.res}

procedure TImagePrint.DrawImage(Canvas: TCanvas; DestRect: TRect; ABitmap: TBitmap);
var
  Header, Bits: Pointer;
  HeaderSize: DWORD;
  BitsSize: DWORD;
begin
  GetDIBSizes(ABitmap.Handle, HeaderSize, BitsSize);
  Header := AllocMem(HeaderSize);
  Bits := AllocMem(BitsSize);
  try
    GetDIB(ABitmap.Handle, ABitmap.Palette, Header^, Bits^);
    StretchDIBits(Canvas.Handle, DestRect.Left, DestRect.Top,
      DestRect.Right, DestRect.Bottom,
      0, 0, ABitmap.Width, ABitmap.Height, Bits, TBitmapInfo(Header^),
      DIB_RGB_COLORS, SRCCOPY);
  finally
    FreeMem(Header, HeaderSize);
    FreeMem(Bits, BitsSize);
  end;
end;

procedure TImagePrint.PrintImage(Image: TImage; ZoomPercent: Integer);
//jeśli ZoomPercent = 100, obraz zostanie wydrukowany na całej powierzchni strony
var
  relHeight, relWidth: integer;
begin
  Screen.Cursor := crHourglass; //ustawienie kursora na klepsydrę
  Printer.BeginDoc;
  with Image.Picture.Bitmap do
  begin
    if ((Width / Height) > (Printer.PageWidth / Printer.PageHeight)) then
    begin
      // rozciągniecie obrazka do szerokości strony drukarki
      relWidth := Printer.PageWidth;
      relHeight := MulDiv(Height, Printer.PageWidth, Width);
    end
    else
    begin
      // rozciagniecie obrazka do wysokosci strony drukarki
      relWidth  := MulDiv(Width, Printer.PageHeight, Height);
      relHeight := Printer.PageHeight;
    end;
    relWidth := Round(relWidth * ZoomPercent / 100);
    relHeight := Round(relHeight * ZoomPercent / 100);
    DrawImage(Printer.Canvas, Rect(0, 0, relWidth, relHeight), Image.Picture.Bitmap);
  end;
  Printer.EndDoc;
  Screen.cursor := crDefault;
end;

procedure Register;
begin
  RegisterComponents('Mario', [TImagePrint]);
end;

end.

Możesz to zrobić np w ten sposób:
Dajesz Image na formę i

Image1.Height:=2065;
Image1.Width:=1470;

Dajesz też PrinterSetupDialog na formę.
No i w OnClick dla jakiegoś buttonka wpis

procedure TForm1.Button1Click(Sender: TObject);
begin
  if PrinterSetupDialog1.Execute then //Tu sobie ustawiasz jakość wudruku
  ImagePrint1.PrintImage(Image1, 100);
end;

...i powinno być ok ;-)